二、创建批处理工具查杀方法

最近中了jun.exe病毒，其实没什么危害，就是打不开u盘，卡巴斯基总是报错但还处理不了。这里是郡主朋友制作的专杀工具，简单快速。

打开记事本，将以下内容复制到里面，然后另存为.bat为后缀名的文件,并双击运行,即可清除之.

@echo off
color 0a
title "jun.exe"病毒专杀(β1.0)
echo.
echo ================【"jun.exe"病毒专杀(β1.0)】=================
echo.
echo 作者：郡主(mamimoluo)
echo 作者主页：http://hi.baidu.com/mimimo
echo eMail：mamimoluo@126.com
echo QQ:260_487_299
echo 2007-8-10
echo ==========================================================
set /p msg=按回车键开始杀毒!
cls
echo.
echo 正在准备杀毒,请稍候...
echo ----------------------
echo.
taskkill /s 127.0.0.1 /f /im explorer.exe >nul 2>nul
echo 正在终止病毒进程...
echo ----------------------
taskkill /s 127.0.0.1 /f /im jun.exe >nul 2>nul
echo ----------------------完成!
echo.
echo 正在删除病毒文件...
echo ----------------------
for %%f in (jun.exe,oemlogo.bmp,oeminfo.ini) do (
IF EXIST "%SYSTEMROOT%\system32\%%f" (
del /f/q/a "%SYSTEMROOT%\system32\%%f"
echo 病毒文件- "%%f" -删除成功!
) ELSE (
echo "%%f" -不存在!
)
)
echo ----------------------完成!
echo.
echo 正在清除病毒自启动文件...
echo ----------------------
for %%D in (C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z) do (
for %%a in (jun.exe,autorun.inf) do (
IF EXIST %%D:\%%a (
del /f/q/a %%D:\%%a
echo 自启动文件- "%%a" -删除成功!
)
)
)
echo ----------------------完成!
echo.
echo 正在删除注册表项...
echo ----------------------
reg delete "hklm\Software\Microsoft\Windows\CurrentVersion\Run" /v jun /f 2<nul
echo ----------------------完成!
echo.
echo =================【"jun.exe"病毒清除成功】==================
echo.
echo 谢谢使用！
echo 您现在可以关闭此程序。
echo.
echo ==========================================================
echo.
%SYSTEMROOT%\explorer.exe
pause

 

转截请注明:文章来自 pc捍卫者 http://www.pchwz.com 本站发布此文为传递更多信息之目的,不表明pc捍卫者赞同其观点